アサマデザイン研究所

POV-Ray

WEBサイト : POV-Ray
ライセンス : POV-Ray License
Operating system : Windows/Mac OS/Mac OS X/i86 Linux
ダウンロード : http://www.povray.org/download/

インストール

Windows

POVRAY station
初心者向け講座 - ２．POVRAYをダウンロードする

Linux

POV-Ray
Step-by-step tutorial for installing POV-Ray on a GNU/Linux system

Debian/Ubuntu

$sudo aptitude install povray

日本語マニュアル

POV-Ray3.5和訳

POV-Ray3.5 日本語マニュアル

Back to top

簡単なチュートリアル

Windows

[File]→[New File]
[Insert]→[Scene template]→[Basic scene]
[File]→[Save As...]
ファイル名(例:sample.pov)を入力して保存

Windowsサンプル01

[Render]→[Start Rendering]

レンダリングが始まり下のような画像が作成されます。

Windowsサンプル02

Back to top

Linux

以下のような内容のテキストファイルを作成(例:sample.pov)

#include "colors.inc"
#include "shapes.inc"
#include "stones.inc"

camera{
    location<5,5,-10>
    look_at<0,0,0>
    angle 20
}

light_source{<0,10,-10> color White}

object{
    Sphere
    texture{T_Stone12}
}

ターミナルで以下のように入力してレンダリングします。

$ povray +isample.pov +w320 +h240 +p

Linuxサンプル画像

Back to top

チュートリアル - Mug

以下のような内容のシーンファイルを作成(例:mug.pov)

#version 3.6;

#include "colors.inc"

global_settings {
  assumed_gamma 1.0
}

// ----------------------------------------

camera {
  location  < 6.0, 6.0, -6.0>
  direction 1.5*z
  right     x*image_width/image_height
  look_at   <0.0, 1.6,  0.0>
}

sky_sphere {
  pigment {
    gradient y
    color_map {
      [0.0 rgb <0.6,0.7,1.0>]
      [0.7 rgb <0.0,0.1,0.8>]
    }
  }
}

light_source {
  <0, 0, 0>            // light's position (translated below)
  color rgb <1, 1, 1>  // light's color
  translate <-30, 30, -30>
}

// ----------------------------------------

plane {               // checkered floor
  y, 0
  texture
  {
    pigment {
      checker
      color rgb 1
      color blue 1
      scale 1.5
    }
    finish{
      diffuse 0.8
      ambient 0.1
    }
  }
}

union {             //カップとハンドルの結合
   union {             //カップ
      difference { 
         cylinder { <0, 3.5, 0>, <0, 0, 0>, 1.5 }
         cylinder { <0, 3.6, 0>, <0, 0.1, 0>, 1.3 }
      }
      
      torus {
         1.4, 0.1
         translate y*3.5
      }
   }
   
   difference {   //ハンドル
      union {
         difference {
            torus {
               1, 0.15
               rotate z*90
            }
            
            box { <-0.5, -1.2, -1.2>, <0.5, 0, 1.2> }
            translate y*0.3
         }
         
         difference {
            torus {
               1, 0.15
               rotate z*90
            }
            
            box { <-0.5, -1.2, -1.2>, <0.5, 0, 1.2> }
            rotate z*180
            translate y*(-0.3)
         }
         
         cylinder {
            <0, 0.3, 0>, <0, -0.3, 0>, 0.15
            translate z*(-1)
         }
         translate <0, 2, -1.5>
         scale <2, 1, 1>
      }
   
      cylinder { <0, 3.5, 0>, <0, 0, 0>, 1.5 }  
   
   }
   texture {   
      pigment { color rgb <1.0, 1.0, 1.0> }
      finish { reflection { 0.03 0.4 } }
   }
}

レンダリング。

povray-mug

Back to top